package synthas_ui

v2 :: [2]f32
rect2 :: struct {x, y, width, height: f32}

@private rect_get_tl :: #force_inline proc(rect: rect2) -> v2 {return {rect.x, rect.y}}
@private rect_get_tr :: #force_inline proc(rect: rect2) -> v2 {return {rect.x + rect.width, rect.y}}
@private rect_get_br :: #force_inline proc(rect: rect2) -> v2 {return {rect.x + rect.width, rect.y + rect.height}}
@private rect_get_bl :: #force_inline proc(rect: rect2) -> v2 {return {rect.x, rect.y + rect.height}}

@private rect_grow :: proc(rect: rect2, amount: v2) -> rect2 {
	return {rect.x - amount.x / 2.0, rect.y - amount.y / 2.0, rect.width + amount.x, rect.height + amount.y}
}

@private ctx: ^Context

Context :: struct {
	origin: v2,
	containers: [dynamic]int,
	container_last_element: [dynamic]int,
	elements: [dynamic]Element,
	same_line: bool,
}

@private CONTAINER_STACK_SIZE :: 16

init :: proc(state: ^Context, element_capacity: int, allocator := context.allocator) {
	state.containers = make(type_of(state.containers), 0, CONTAINER_STACK_SIZE, allocator)
	state.container_last_element = make(type_of(state.container_last_element), 0, CONTAINER_STACK_SIZE, allocator)
	state.elements = make(type_of(state.elements), 0, element_capacity, allocator)
}

Element :: struct {
	area: rect2,
	using config: ElementConfiguration,
	type: ElementType,
}

ElementConfiguration :: struct {
	label: cstring,
	color: [4]u8,
	margin, padding: v2,
}

ElementType :: enum {
	Container,
	Button,
}

Size_Pixels :: distinct f32
Size_Percentage :: distinct f32
Size_Flex :: distinct bool

Size :: union {
	Size_Pixels,
	Size_Percentage,
	Size_Flex,
}

Dimensions :: struct {
	width, height: Size,
}

Axis :: enum {X, Y}

start :: proc(ui_context: ^Context, origin: v2, size: v2) {
	ctx = ui_context
	ctx.origin = origin
	clear(&ctx.elements)
	clear(&ctx.containers)
	clear(&ctx.container_last_element)
	append(&ctx.elements, Element{
		area = {**origin, **size},
		label = "",
		color = {0, 0, 0, 0},
		margin = {},
		padding = {},
		type = .Container})
	append(&ctx.containers, 0)
	append(&ctx.container_last_element, -1)
}

end :: proc() -> []Element {
	assert(len(ctx.containers) < 2, "Didn't close all containers before ending UI layout mode")
	assert(len(ctx.containers) > 0, "Closed base container before ending UI layout mode")
	elements := ctx.elements[:]
	ctx = nil
	return elements
}

same_line :: proc() {
	ctx.same_line = true
}

element_get_outer_area :: proc(element: Element) -> rect2 {
	return rect_grow(element.area, element.margin * 2.0)
}

element_get_inner_area :: proc(element: Element) -> rect2 {
	return rect_grow(element.area, -element.padding * 2.0)
}

container_begin :: proc(dimensions: Dimensions, config: ElementConfiguration) {
	position: v2
	if len(ctx.containers) == 0 {
		position = ctx.origin + config.margin
	} else {
		if alignment_element := _element_container_previous(); alignment_element != nil {
			position = rect_get_tl(element_get_inner_area(alignment_element^)) + config.margin
		} else {
			position = rect_get_tl(element_get_inner_area(_element_previous()^)) + config.margin
		}
	}
	size := _resolve_dimensions(dimensions) - config.margin * 2.0
	element := Element{area = rect2{**position, **size}, config = config, type = .Container}
	_append_element(element)
	container_index := len(ctx.elements) - 1
	append(&ctx.containers, container_index)
	append(&ctx.container_last_element, -1)
}

@private _append_element :: proc(element: Element) {
	append(&ctx.elements, element)
	ctx.container_last_element[len(ctx.containers) - 1] = len(ctx.elements) - 1
}

container_end :: proc() {
	container := ctx.elements[pop(&ctx.containers)]
	pop(&ctx.container_last_element)
	// TODO: Set flex
	outer := element_get_outer_area(container)
}

button :: proc(dimensions: Dimensions) {
}

_resolve_dimensions :: proc(dimensions: Dimensions) -> v2 {
	return {_resolve_size(dimensions.width, .X), _resolve_size(dimensions.height, .Y)}
}

_resolve_size :: proc(size: Size, axis: Axis) -> f32 {
	switch value in size {
	case Size_Pixels:
		return cast(f32)value
	case Size_Percentage:
		if container := _container_current(); container != nil {
			inner := element_get_inner_area(container^)
			container_size := inner.width if axis == .X else inner.height
			return container_size * cast(f32)value
		} else {
			panic("Cannot use dimension Size_Percentage without an outer container")
		}
	case Size_Flex:
		return 0.0
	}
	unreachable()
}

_container_current :: proc() -> ^Element {
	return &ctx.elements[ctx.containers[len(ctx.containers) - 1]]
}

_element_previous :: proc() -> ^Element {
	return &ctx.elements[len(ctx.elements) - 1]
}

_element_container_previous :: proc() -> ^Element {
	if previous_index := ctx.container_last_element[len(ctx.containers) - 1]; previous_index != -1 {
		return &ctx.elements[previous_index]
	} else {
		return nil
	}
}