package main

import rl "libraries/raylib"
import ui "libraries/snths_ui"
import "core:fmt"

FontStyle :: struct {
	font: rl.Font,
	size, spacing: f32
}

ProgramState :: enum {
	Normal,
	Message,
}

ProgramMessageType :: enum {
	ChangeMatrixTypeClearData,
}

@rodata program_messages := [ProgramMessageType]cstring {
	.ChangeMatrixTypeClearData = "Changing the matrix type will delete all current matrices.\nAre you sure you want to do this?",
}

program_set_message_state :: proc(program: ^Program, message: ProgramMessageType) {
	program.state = .Message
	program.message_type = message
}

program: Program

InputFloatField :: [32]byte
MATRIX_POOL_SIZE :: 4096

input_float_field_as_cstring :: proc(field: ^InputFloatField) -> cstring {
	return cstring(&field[0])
}

Program :: struct {
	ui_context: ui.Context,
	matrix_float_pool: []f32,
	matrix_value_string_pool: []InputFloatField,
	matrix_count: int,
	grid: Grid,
	font_style: FontStyle,
	state: ProgramState,
	message_type: ProgramMessageType,
}

Grid :: struct {
	area:        rect2,
	inner_area:  rect2,
	zoom:        f32,
}

matrix_pool_max :: proc() -> int {
	return len(program.matrix_float_pool) / 9
}

matrix_pool_get_mat3 :: proc() -> ^mat3 {
	assert(program.matrix_count + 1 < matrix_pool_max(), "Max matrix count exceeded")
	mat := cast(^mat3)&program.matrix_float_pool[program.matrix_count * 9]
	program.matrix_count += 1
	return mat
}

program_init :: proc(allocator := context.allocator) {
	program.matrix_float_pool = make(type_of(program.matrix_float_pool), MATRIX_POOL_SIZE)
	program.matrix_value_string_pool = make(type_of(program.matrix_value_string_pool), MATRIX_POOL_SIZE)
	program.font_style = {
		font = rl.GetFontDefault(),
		size = 16.0,
		spacing = 1.0
	}
	program.grid = {
		area = {0, 0, WINDOW_WIDTH, WINDOW_HEIGHT},
		inner_area = {-1, -1, 2, 2},
		zoom = 1.0,
	}
	ui.init(&program.ui_context, 4000, allocator)
}

program_update :: proc() {
	if rl.IsKeyPressed(.ENTER) {
		matrix_pool_get_mat3()
	}
	ui_elements := program_build_ui()
	if rl.IsKeyPressed(.TAB) {
		ui.focus_next_element(&program.ui_context)
	}
	program_render_ui(&program.ui_context, ui_elements)
}

program_build_ui :: proc() -> []ui.Element {
	container_margin: f32 = 4.0
	container_config := ui.ElementConfiguration {
		margin = V2_ONE * container_margin,
	}

	ui.start(&program.ui_context, {0, 0}, {WINDOW_WIDTH, WINDOW_HEIGHT})
	top_bar_container := ui.container_begin({ui.Size_Percentage(1.0), ui.Size_Pixels(48.0)}, container_config)
	top_bar_inner_height := ui.get_element_inner_area(top_bar_container^).height
	top_bar_button_dimensions := ui.Dimensions {ui.Size_Pixels(top_bar_inner_height), ui.Size_Pixels(top_bar_inner_height)}
	top_bar_button_config := ui.ElementConfiguration {margin = V2_ONE * 4}
	{
		config := top_bar_button_config
		config.label = "+"
		ui.button(top_bar_button_dimensions, config)
		config.label = "-"
		ui.same_line()
		ui.button(top_bar_button_dimensions, config)
	}
	ui.container_end()

	ui.container_begin({ui.Size_Percentage(0.2), ui.Size_PercentageRemainder(1.0)}, container_config)
	for i in 0..<program.matrix_count {
		container_config := ui.ElementConfiguration{margin = V2_ONE * 4.0, label = fmt.ctprintf("Matrix %d", i)}
		container_dimensions := ui.Dimensions {ui.Size_Percentage(1.0), ui.Size_Pixels(112.0)}
		mat := cast(^mat3)&program.matrix_float_pool[i * 9]
		value_strings := program.matrix_value_string_pool[i * 9 : i * 9 + 9]
		ui_mat3(mat, value_strings, container_dimensions, container_config)
	}
	ui.container_end()
	return ui.end()
}

ui_mat3 :: proc(mat: ^mat3, value_strings: []InputFloatField, dimensions: ui.Dimensions, config: ui.ElementConfiguration) {
	ui.container_begin(dimensions, config)
		matrix_input_config := ui.ElementConfiguration {margin = V2_ONE * 4.0}
		matrix_input_dimensions := ui.Dimensions {ui.Size_Percentage(1.0 / 3.0), ui.Size_Percentage(1.0 / 3.0)}
		#unroll for i in 0..<3 {
			data: ui.ElementData_FloatInput
			data = {value = &mat[i, 0], value_string = input_float_field_as_cstring(&value_strings[i * 3 + 0])}
			ui.input_float(matrix_input_dimensions, matrix_input_config, data)
			ui.same_line()
			data = {value = &mat[i, 1], value_string = input_float_field_as_cstring(&value_strings[i * 3 + 1])}
			ui.input_float(matrix_input_dimensions, matrix_input_config, data)
			ui.same_line()
			data = {value = &mat[i, 2], value_string = input_float_field_as_cstring(&value_strings[i * 3 + 2])}
			ui.input_float(matrix_input_dimensions, matrix_input_config, data)
		}
	ui.container_end()
}

program_render_ui :: proc(ctx: ^ui.Context, elements: []ui.Element) {
	for element in elements {
		area := rl.Rectangle(element.area)
		switch element.type {
		case .Container:
			rl.GuiGroupBox(area, element.label)
		case .Button:
			rl.GuiButton(area, element.label)
		case .Slider:
			data := element.data
			rl.GuiSlider(area, element.label, "", data.value, data.min, data.max)
		case .InputFloat:
			data := element.data
			if rl.GuiValueBoxFloat(area, element.label, data.value_string, data.value, ui.is_element_focused(ctx, element)) == 1 {
				ui.focus_element(ctx, element)
			}
		}
	}
}